init commit

.SRCINFO

@@ -0,0 +1,33 @@
+pkgbase = keepassxc-allow-aur-extension-origin
+	pkgdesc = Cross-platform community-driven port of Keepass password manager
+	pkgver = 2.7.1
+	pkgrel = 1
+	url = https://keepassxc.org/
+	arch = x86_64
+	license = GPL
+	checkdepends = xclip
+	checkdepends = xorg-server-xvfb
+	makedepends = asciidoctor
+	makedepends = cmake
+	makedepends = qt5-tools
+	depends = argon2
+	depends = botan
+	depends = curl
+	depends = hicolor-icon-theme
+	depends = libxtst
+	depends = minizip
+	depends = pcsclite
+	depends = qrencode
+	depends = qt5-svg
+	depends = qt5-x11extras
+	optdepends = xclip: keepassxc-cli clipboard support under X server
+	optdepends = wl-clipboard: keepassxc-cli clipboard support under Wayland
+	provides = org.freedesktop.secrets
+	provides = keepassxc
+	conflicts = keepassxc
+	source = https://github.com/keepassxreboot/keepassxc/releases/download/2.7.1/keepassxc-2.7.1-src.tar.xz
+	source = add-aur-extension-build-to-allowed-origins.patch
+	sha256sums = 6001ba626c35c316dbda6de35736f012a2264f95139fcb4a094b8eb49b15d3e7
+	sha256sums = a150f3ce0d9d8827b6c767aa673be4af298aafd6f46ddd10373e32b832dd2017
+
+pkgname = keepassxc-allow-aur-extension-origin

.gitignore

@@ -0,0 +1,3 @@
+*.tar.*
+src/
+pkg/

PKGBUILD

@@ -0,0 +1,50 @@
+# Maintainer: Balló György <ballogyor+arch at gmail dot com>
+# Maintainer: Bruno Pagani <archange@archlinux.org>
+
+pkgname=keepassxc-allow-aur-extension-origin
+pkgver=2.7.1
+pkgrel=1
+pkgdesc="Cross-platform community-driven port of Keepass password manager"
+arch=(x86_64)
+url="https://keepassxc.org/"
+license=(GPL)
+depends=(argon2 botan curl hicolor-icon-theme libxtst
+         minizip pcsclite qrencode qt5-svg qt5-x11extras)
+makedepends=(asciidoctor cmake qt5-tools)
+optdepends=('xclip: keepassxc-cli clipboard support under X server'
+            'wl-clipboard: keepassxc-cli clipboard support under Wayland')
+checkdepends=(xclip xorg-server-xvfb)
+provides=(org.freedesktop.secrets keepassxc)
+conflicts=(keepassxc)
+source=(https://github.com/keepassxreboot/keepassxc/releases/download/$pkgver/keepassxc-$pkgver-src.tar.xz
+        add-aur-extension-build-to-allowed-origins.patch)
+sha256sums=('6001ba626c35c316dbda6de35736f012a2264f95139fcb4a094b8eb49b15d3e7'
+            'a150f3ce0d9d8827b6c767aa673be4af298aafd6f46ddd10373e32b832dd2017')
+# List of signing keys can be found at https://keepassxc.org/verifying-signatures/
+# validpgpkeys=(BF5A669F2272CF4324C1FDA8CFB4C2166397D0D2
+#               71D4673D73C7F83C17DAE6A2D8538E98A26FD9C4
+#               AF0AEA44ABAC8F1047733EA7AFF235EEFB5A2517
+#               C1E4CBA3AD78D3AFD894F9E0B7A66F03B59076A8)
+
+prepare() {
+    cd keepassxc-"$pkgver"
+    patch -p1 -i ../add-aur-extension-build-to-allowed-origins.patch
+}
+
+build() {
+  cmake -S keepassxc-$pkgver -B build \
+    -DCMAKE_BUILD_TYPE=Release \
+    -DCMAKE_INSTALL_PREFIX=/usr \
+    -DCMAKE_INSTALL_LIBDIR=lib \
+    -DWITH_XC_ALL=ON \
+    -DWITH_XC_UPDATECHECK=OFF
+  cmake --build build
+}
+
+# check() {
+#   xvfb-run --auto-servernum cmake --build build --target test
+# }
+
+package() {
+  cmake --build build --target install -- DESTDIR="$pkgdir"
+}

add-aur-extension-build-to-allowed-origins.patch

@@ -0,0 +1,12 @@
+--- a/src/browser/NativeMessageInstaller.cpp
++++ b/src/browser/NativeMessageInstaller.cpp
+@@ -40,7 +40,8 @@ namespace
+     const QStringList ALLOWED_EXTENSIONS = QStringList() << QStringLiteral("keepassxc-browser@keepassxc.org");
+     const QStringList ALLOWED_ORIGINS = QStringList()
+                                         << QStringLiteral("chrome-extension://pdffhmdngciaglkoonimfcmckehcpafo/")
+-                                        << QStringLiteral("chrome-extension://oboonakemofpalcgghocfoadofidjkkk/");
++                                        << QStringLiteral("chrome-extension://oboonakemofpalcgghocfoadofidjkkk/")
++                                        << QStringLiteral("chrome-extension://pcjdfoihcobckdlnlcpbpkaokdmpemfj/");
+ #if defined(Q_OS_MACOS)
+     const QString TARGET_DIR_CHROME = QStringLiteral("/Library/Application Support/Google/Chrome/NativeMessagingHosts");
+     const QString TARGET_DIR_CHROMIUM = QStringLiteral("/Library/Application Support/Chromium/NativeMessagingHosts");