| 123456789101112131415161718192021222324252627282930313233343536373839404142434445464748 |
- # Maintainer: Noah Vogt (noahvogt) <noah@noahvogt.com>
- # Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
- # Contributor: Ionut Biru <ibiru@archlinux.org>
- pkgname=networkmanager-openvpn-xdg
- pkgver=1.8.16
- pkgrel=1
- pkgdesc="NetworkManager VPN plugin for OpenVPN - with Support for the XDG Base Directory Specification"
- url="https://wiki.gnome.org/Projects/NetworkManager"
- arch=(x86_64)
- license=(GPL)
- depends=(libnm libsecret openvpn)
- makedepends=(libnma intltool python git)
- optdepends=('libnma: GUI support')
- _commit=ac02405a34427c4f9e2392914af1a076e1c8744e # tags/1.8.16^0
- source=("git+https://gitlab.gnome.org/GNOME/NetworkManager-openvpn.git#commit=$_commit"
- "xdg-basedir.patch")
- sha256sums=('SKIP'
- '25d1e22354f2ce30871654fa3bfebfe19dfe82432f0c4998ccd62b0c05727cba')
- pkgver() {
- cd NetworkManager-openvpn
- git describe --tags | sed 's/-dev/dev/;s/-/+/g'
- }
- prepare() {
- cd NetworkManager-openvpn
- patch -Np1 -i ../xdg-basedir.patch
- intltoolize --automake --copy
- autoreconf -fvi
- }
- build() {
- cd NetworkManager-openvpn
- ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
- --libexecdir=/usr/lib --disable-static
- sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
- make
- }
- package() {
- cd NetworkManager-openvpn
- make DESTDIR="$pkgdir" install dbusservicedir=/usr/share/dbus-1/system.d
- echo 'u nm-openvpn - "NetworkManager OpenVPN"' |
- install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
- }
- # vim:set sw=2 et:
|
