init commit

.SRCINFO

@@ -0,0 +1,21 @@
+pkgbase = networkmanager-openvpn-xdg
+	pkgdesc = NetworkManager VPN plugin for OpenVPN - with Support for the XDG Base Directory Specification
+	pkgver = 1.8.16
+	pkgrel = 1
+	url = https://wiki.gnome.org/Projects/NetworkManager
+	arch = x86_64
+	license = GPL
+	makedepends = libnma
+	makedepends = intltool
+	makedepends = python
+	makedepends = git
+	depends = libnm
+	depends = libsecret
+	depends = openvpn
+	optdepends = libnma: GUI support
+	source = git+https://gitlab.gnome.org/GNOME/NetworkManager-openvpn.git#commit=ac02405a34427c4f9e2392914af1a076e1c8744e
+	source = xdg-basedir.patch
+	sha256sums = SKIP
+	sha256sums = 25d1e22354f2ce30871654fa3bfebfe19dfe82432f0c4998ccd62b0c05727cba
+
+pkgname = networkmanager-openvpn-xdg

PKGBUILD

@@ -0,0 +1,48 @@
+# Maintainer: Noah Vogt (noahvogt) <noah@noahvogt.com>
+# Contributor: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
+# Contributor: Ionut Biru <ibiru@archlinux.org>
+
+pkgname=networkmanager-openvpn-xdg
+pkgver=1.8.16
+pkgrel=1
+pkgdesc="NetworkManager VPN plugin for OpenVPN - with Support for the XDG Base Directory Specification"
+url="https://wiki.gnome.org/Projects/NetworkManager"
+arch=(x86_64)
+license=(GPL)
+depends=(libnm libsecret openvpn)
+makedepends=(libnma intltool python git)
+optdepends=('libnma: GUI support')
+_commit=ac02405a34427c4f9e2392914af1a076e1c8744e  # tags/1.8.16^0
+source=("git+https://gitlab.gnome.org/GNOME/NetworkManager-openvpn.git#commit=$_commit"
+        "xdg-basedir.patch")
+sha256sums=('SKIP'
+            '25d1e22354f2ce30871654fa3bfebfe19dfe82432f0c4998ccd62b0c05727cba')
+
+pkgver() {
+  cd NetworkManager-openvpn
+  git describe --tags | sed 's/-dev/dev/;s/-/+/g'
+}
+
+prepare() {
+  cd NetworkManager-openvpn
+  patch -Np1 -i ../xdg-basedir.patch
+  intltoolize --automake --copy
+  autoreconf -fvi
+}
+
+build() {
+  cd NetworkManager-openvpn
+  ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
+    --libexecdir=/usr/lib --disable-static
+  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
+  make
+}
+
+package() {
+  cd NetworkManager-openvpn
+  make DESTDIR="$pkgdir" install dbusservicedir=/usr/share/dbus-1/system.d
+  echo 'u nm-openvpn - "NetworkManager OpenVPN"' |
+    install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
+}
+
+# vim:set sw=2 et:

xdg-basedir.patch

@@ -0,0 +1,11 @@
+--- a/properties/import-export.c	2021-11-05 15:44:34.849854542 +0100
++++ b/properties/import-export.c    2021-11-05 15:46:45.569146375 +0100
+@@ -696,7 +696,7 @@
+ 	if (_nmovpn_test_temp_path)
+ 		return g_build_filename (_nmovpn_test_temp_path, f_filename, NULL);
+ 
++	return g_build_filename (g_get_home_dir (), ".local/share/cert/nm-openvpn", f_filename, NULL);
+-	return g_build_filename (g_get_home_dir (), ".cert/nm-openvpn", f_filename, NULL);
+ }
+ 
+ static gboolean